(*~\Глагол\Отделы\Поле~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
(**)                        ОТДЕЛ Подложка;
(*============================================================================* 
 * НАЗНАЧЕНИЕ: подложка под поле
 *============================================================================*)
ИСПОЛЬЗУЕТ 
  Надел,
  Поле,
  Цепь ИЗ "..\Иное\",
  Окно ИЗ "..\Обмен\",
  Ввод ИЗ "..\Обмен\";
ВИД
  Доступ-=ДОСТУП К Вид;
  Вид-=НАБОР(Надел.Вид)
    заголовок:Надел.Надпись
  КОН;

(******************************************************************************)
ЗАДАЧА Отрисовка(подложка:Доступ);
ПЕР
  позЗаглавия:ЦЕЛ;
  вс,лк,нс,пк:ЦЕЛ;
УКАЗ
  вс:=подложка.вс;
  лк:=подложка.лк;
  нс:=подложка.нс;
  пк:=подложка.пк;
  (* прямоугольник *)
  Надел.Очистить(подложка);
  Окно.Рамка2(вс,лк,нс,пк);
  Окно.Тень(вс,лк,нс,пк);
  (* посерёдке будет заголовок *)
  позЗаглавия:=(лк + пк - ДЛИНА(подложка.заголовок)+1) ДЕЛИТЬ 2;
  Окно.Цепь(вс,позЗаглавия,вс,пк,подложка.заголовок)
КОН Отрисовка;

(******************************************************************************)
ЗАДАЧА Приём(надел:Надел.Доступ; посылка+:Ввод.Посылка);
(* приём посылок извне *)
УКАЗ
  ДЛЯ посылка ВИДА
  | Поле.Отрисовка: Отрисовка(надел(Доступ))
  ИНАЧЕ
  КОН
КОН Приём;

(******************************************************************************)
ЗАДАЧА Создать-(верх,лево,строк,колонок:ЦЕЛ; заголовок-:ЦЕПЬ):Доступ;
ПЕР
  подложка:Доступ;
УКАЗ
  СОЗДАТЬ(подложка);
  Надел.Подготовить(подложка,
                    верх,
                    лево,
                    строк,
                    колонок,
                   {Надел.прГлухой},
                    Приём);
  ЕСЛИ заголовок # "" ТО
    подложка.заголовок:=" ";
    Цепь.Добавить(подложка.заголовок,заголовок);
    Цепь.ДобавитьЗнак(подложка.заголовок," ")
  КОН;
  ВОЗВРАТ подложка
КОН Создать;

КОН Подложка.